Lost Dashboard Widget in Catalina Mac OS 10.15.x Workaround
  • Until it was eliminated in Catalina, MacOS 10.15, Dashboard was my goto for viewing my Security Spy attached cameras.
    I programmed an extra button on my Logitech mouse to trigger Dashboard. This trigger opened (or closed) Dashboard.
    This displayed the Security Spy Dashboard Widgets, one for each camera, with a single click and hid them with another click.

    I missed this feature so I wrote an Applescript to emulate the same behavior in Safari.
    I programmed the same button on my Logitech mouse to trigger this Applescript, saved as an application.
    Now a single click opens new a Safari window which displays my Security Spy attached cameras.
    Another click closes the window.

    Enter your target Security Spy URL and your preferred window configuration in the script and save it as an application.
    Then link the application to your trigger of choice (i.e., an F-Key or a programmed mouse button) to launch the application.
    You can even put the application in your dock.

    Instructions:
    1. Copy and Paste the text below into a new Script Editor document.
    2. Click the Compile button (Command + K).
    3. Configure your "TargetURL" and "TargetURLConfig" values.
    4. Save as an Application.

    [Copy and Paste Everything Below Here]

    --
    --
    -- Until it was eliminated in Catalina, MacOS 10.15, Dashboard was my goto for viewing my Security Spy attached cameras.
    -- I programmed an extra button on my Logitech mouse to trigger Dashboard. This trigger opened (or closed) Dashboard.
    -- This displayed the Security Spy Dashboard Widgets, one for each camera, with a single click and hid them with another click.
    --
    -- I missed this feature so I wrote an Applescript to emulate the same behavior in Safari.
    -- I programmed the same button on my Logitech mouse to trigger this Applescript, saved as an application.
    -- Now a single click opens new a Safari window which displays my Security Spy attached cameras.
    -- Another click closes the window.
    --
    -- Enter your target Security Spy URL and your preferred window configuration in the script and save it as an application.
    -- Then link the application to your trigger of choice (i.e., an F-Key or a programmed mouse button) to launch the application.
    -- You can even put the application in your dock.
    --
    --
    --
    tell application "Safari"
    set TargetURL to "https://YourSecuritySpyURLHere.com:8001/"
    -- Insert your target Security Spy URL here.
    --
    -- If you use a Dynamic DNS service, insert the Dynamic DNS target.
    -- To use a Dynamic DNS service you must configure your router to allow remote access to Security Spy.
    -- You may use a local IP number here but it will work only on the local network.
    --
    set TargetURLConfig to "live?groupSelect1=All+Cameras&cameraNum=4&cameraNum=1&cameraNum=0&cameraNum=5&viewMethod=0&imageSize=640x480&windowWidth=1503&windowHeight=1312&99244"
    -- Insert your window configuration here.
    -- You can capture this string by setting up your preferred view in Safari and copying from the webpage URL.
    --
    try
    if (get URL of document 1) contains TargetURL then
    -- This toggles the Security Spy webpage closed if a previously opened Security Spy webpage is the frontmost window.
    -- With this configuration, a single trigger (i.e., an F-Key or a programmed mouse button) will open and close your Security Spy webpage in a Safari window.
    close document 1
    else if (get URL of document 1) is missing value then
    -- On launch Safari creates a new blank window.
    -- If the script detects that the frontmost window is blank, this closes the frontmost blank window and opens a new Security Spy window.
    close document 1
    make new document with properties {URL:TargetURL & TargetURLConfig}
    activate
    else
    -- This opens a new Security Spy webpage as the frontmost Safari window.
    make new document with properties {URL:TargetURL & TargetURLConfig}
    activate
    end if
    on error errStr number errorNumber
    -- If Safari has no open windows, Safari returns an error.
    -- This captures that error (by number) and opens a new Security Spy webpage as the frontmost Safari window.
    if errorNumber is -1719 then
    make new document with properties {URL:TargetURL & TargetURLConfig}
    activate
    else
    display dialog errStr & return & "Error Number: " & errorNumber
    end if
    end try
    end tell
    --
    --
  • Many thanks for posting this - it works very well!

Howdy, Stranger!

It looks like you're new here. If you want to get involved, click one of these buttons!